Automatisieren Sie die Änderung der Einstellungen beim Anschließen der Maus

Wenn Sie unter macOS Sierra nur eine normale USB-Maus haben , die nicht mit eigener Software geliefert wird und multifunktional mit zusätzlichen Tasten usw. ist, dann haben Sie unter Systemeinstellungen > Maus die folgenden Einstellungen, die geändert werden können:

• Scrollrichtung: natürliches Kontrollkästchen
• Schieberegler für die Tracking-Geschwindigkeit
• Schieberegler für die Scrollgeschwindigkeit
• Doppelklicken Sie auf den Geschwindigkeitsregler

Und zwei zusätzliche Einstellungen unter Maus , die aus zwei Gründen nicht angesprochen werden, die primäre Maustaste: Optionsfelder , wenn andere als die Standardeinstellung von Left , ist aller Wahrscheinlichkeit nach bereits festgelegt und würde sich nicht unbedingt ändern, weil man die ändern möchte Bildlaufrichtung: natürliches Kontrollkästchen , und da das OP USB-Maus angegeben hat , gehe ich davon aus, dass es kein Bluetooth verwendet und die Schaltfläche Bluetooth-Maus einrichten... ignorieren kann .

Diese Antwort wird AppleScript verwenden , um die Vorher- und Nachher- Einstellungen für den Wert der oben aufgeführten Schieberegler zu erhalten , die in dem AppleScript- Code verwendet werden , der nach diesem Code folgt .

Öffnen Sie den Skripteditor , erstellen Sie ein neues Dokument und fügen Sie dann den folgenden Code hinzu :

tell application "System Preferences"
    set current pane to pane id "com.apple.preference.mouse"
    --delay 0.5 -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
    tell application "System Events"
        log "Scrolling speed is set to: " & value in (get properties of slider 1 of front window of application process "System Preferences")
        log "Double-Click speed is set to: " & value in (get properties of slider 2 of front window of application process "System Preferences")
        log "Tracking speed is set to: " & value in (get properties of slider 3 of front window of application process "System Preferences")
    end tell
end tell

Es gibt zwei unterschiedliche Zustände der Bildlaufrichtung: natürliches Kontrollkästchen in Systemeinstellungen > Maus , aktiviert und nicht aktiviert und die Änderung der Schiebereglereinstellungen zwischen den beiden Zuständen .

Der obige Code wird einmal ausgeführt, um die aktuellen Werteinstellungen der Schieberegler zu erhalten . Nehmen Sie dann die gewünschten Einstellungsänderungen an den Schiebereglern für den entgegengesetzten Zustand zu dem vor, als Sie die Werte der ersten Einstellungen für den ersten Zustand gesammelt haben . Führen Sie dann den Code erneut aus, um die differenziellen Einstellungen abzurufen.

Sie werden dann die oben gesammelten Werte in den folgenden Code einfügen . Sie können jeden Schieberegler , der nicht durch den folgenden Code geändert wird, auskommentieren oder entfernen.

Die Kommentare im folgenden Code sollten angemessen sein, aber zögern Sie nicht, ihn zu fragen, wenn Sie etwas erklärt brauchen.

Ich habe den folgenden AppleScript- Code im Skripteditor als Anwendung mit dem Namen „Toggle Mouse Settings“ im Ordner „Applications“ gespeichert .

Wenn es ausgeführt wird, schaltet es den Zustand des Kontrollkästchens „Bildlaufrichtung: Natürlich“ zwischen aktiviert und nicht aktiviert um, zusammen mit den Schiebereglereinstellungen unter jedem Status .

AppleScript- Code für die Toggle Mouse Settings -App:

on run
    try
        tell application "System Preferences"
            set current pane to pane id "com.apple.preference.mouse"
            -- delay 0.5    -- # If necessary, uncomment 'delay' command and set its value in seconds and or decimal fractions there of.
            tell application "System Events"
                set isChecked to get value of checkbox 1 of front window of application process "System Preferences" as boolean
                if isChecked then
                    --  # The 'Scroll direction: Natural' checkbox is checked, uncheck it.
                    set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
                    --  # Scrolling Speed - Valid Values: 0.0 to 8.0
                    set value of slider 1 of front window of application process "System Preferences" to 6.0
                    --  # Double-Click Speed - Valid Values: 0.0 to 10.0
                    set value of slider 2 of front window of application process "System Preferences" to 8.0
                    --  # Tracking Speed - Valid Values: 0.0 to 9.0
                    set value of slider 3 of front window of application process "System Preferences" to 6.0
                else
                    --  # The 'Scroll direction: Natural' checkbox is not checked, check it.
                    set cbValue to value of (click checkbox 1 of front window of application process "System Preferences") as boolean
                    --  # Scrolling Speed - Valid Values: 0.0 to 8.0
                    set value of slider 1 of front window of application process "System Preferences" to 4.5
                    --  # Double-Click Speed - Valid Values: 0.0 to 10.0
                    set value of slider 2 of front window of application process "System Preferences" to 8.0
                    --  # Tracking Speed - Valid Values: 0.0 to 9.0
                    set value of slider 3 of front window of application process "System Preferences" to 4.0
                end if
            end tell
            tell me
                if cbValue then
                    display notification "Natural scrolling is now active." with title (name of me)
                else
                    display notification "Natural scrolling is no longer active." with title (name of me)
                end if
            end tell
            quit
        end tell
    on error eStr number eNum
        activate
        display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with title "Toggle Mouse Settings" with icon caution
        tell application "System Preferences" to quit
        return
    end try
end run

Hinweis: Bevor Sie die Toggle Mouse Settings- App ausführen, müssen Sie sie hinzufügen zu: Systemeinstellungen > Sicherheit & Datenschutz > Datenschutz > Eingabehilfen

---

Es gibt eine App namens EventScripts , die zum Auslösen verwendet werden kann, wenn ein USB-Gerät angeschlossen und/oder entfernt wird. Ich habe es noch nie benutzt, ich weiß nur, dass es existiert.

Es gibt auch eine App namens Scroll Reverser . Ich habe es noch nie benutzt, ich weiß nur, dass es existiert.