Beantworten Sie E-Mails automatisch mit Mail & AppleScript & Automator

Auf meinem Computer sind Dutzende von Telefonkonferenznummern gespeichert. Diese Nummern sind alle Nummern, wie z. B. 40027683, keine anderen Zeichen. Diese Nummern werden in einer txt-Datei gespeichert.Geben Sie hier die Bildbeschreibung ein

Einige meiner Benutzer benötigen möglicherweise eine Nummer, wenn sie versuchen, eine Telefonkonferenz mit ihren Kunden durchzuführen. Jedes Mal, wenn die Benutzer eine Konferenzrufnummer per E-Mail anfordern, antworte ich mit einer Nummer.

Gibt es eine Möglichkeit, diese Mails zu beantworten, die automatisch Rückrufnummern erfordern? Ich möchte Mail, AppleScript und Automator ausprobieren.

Ich möchte Mail bitten, AppleScript auszuführen, wenn eine neue E-Mail (der Betreff oder der Nachrichteninhalt enthält das Schlüsselwort „concall“) empfangen wurde, hier ein Beispiel:

Geben Sie hier die Bildbeschreibung ein

Das von mir geschriebene AppleScript wird ausgeführt, um die erste Nummer aus der txt-Datei aufzurufen. Wenn das nächste Mal eine andere Nachricht eintrifft, führt Mail AppleScript aus, um die zweite Nummer der TXT-Datei aufzurufen. Gibt es eine Möglichkeit, dies zu erreichen?

Jeder Vorschlag wäre sehr willkommen.

Könnten Sie das AppleScript, das Sie bisher haben, in Ihre Frage aufnehmen? Sie könnten verwendete Codes in einer anderen Datei ablegen. Also, wenn Sie eine andere Mail erhalten. Sie nehmen einfach wieder den ersten Code.
Entschuldigung, ich habe es nicht deutlich gemacht. Ich habe jetzt keine Codes. Weil ich nicht weiß, wie ich die Nummern aus der TXT-Datei aufrufen oder wie ich die Nummer innerhalb des Skripts aufrufen soll. Was ich erreichen möchte, ist Folgendes: Wenn eine neue E-Mail eintrifft (mit dem Betreff oder Inhalt: concall ), führt Mail AppleScript aus, um die erste Zeile der txt-Datei aufzurufen. Dann ist eine weitere Mail eingetroffen, Mail führt AppleScript aus, um die zweite Zeile der txt-Datei aufzurufen.

Antworten (1)

Sie können es so machen:

property the_numbers : {10000, 20000, 30000}
using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule
        repeat with i from 1 to count of theMessages
            tell application "Mail"
                set the_sender to sender of item i of theMessages
                set the_subject to subject of item i of theMessages
                set the_counter to item 1 of the_numbers
                -- make the outgoing message (the reply)
                set the_reply to make new outgoing message with properties ¬
                    {subject:"Re: " & the_subject, content:"Use this number-- " & the_counter}
                tell the_reply
                    make new to recipient at end of to recipients with properties {address:the_sender}
                end tell
                send the_reply
            end tell
            -- this is the step that deletes item 1 from the list 
            set the_numbers to items 2 thru -1 of the_numbers
        end repeat
    end perform mail action with messages
end using terms from

Das funktioniert, aber Sie müssen ein wenig arbeiten, um Ihre Zahlenliste in eine AppleScript-Liste zu bekommen. Sie setzen sie oben, getrennt durch Kommas, und ersetzen meine 10000, 20000, 30000.

Ich nenne die Liste der Nummern "the_numbers". Indem wir es eine Eigenschaft nennen, speichern wir den Wert von the_numbers von Lauf zu Lauf. Wenn Sie mein Skript unverändert anstelle von "Untitled 3" in der von Ihnen eingerichteten Regel verwenden würden, würde das Skript beim ersten Aufruf mit {10000, 20000, 30000} arbeiten. Bei der nächsten Ausführung wird die Liste {20000, 30000} sein. Wenn es das nächste Mal ausgeführt wird, ist es {30000}. Es ist auch {30000} für alle nachfolgenden Läufe. Ich gehe davon aus/hoffe, dass Sie eine sehr lange Liste von Nummern haben und Ihnen nicht ausgehen wird.

Ein besseres Skript würde Sie wissen lassen, dass die Liste der Zahlen bis zur letzten reicht.

Vielen Dank, Christian. Dein Skript funktioniert bei mir. Ich weiß nicht, wie ich dir danken soll. Ich möchte dir ein Dutzend Bier kaufen. Kann ich 10 $ für Ihr Skript bezahlen? Bitte teilen Sie mir mit, wie ich Ihnen das Geld überweisen soll.
Du bist herzlich Willkommen. Zu wissen, dass ich dir geholfen habe, ist sehr befriedigend und völlig ausreichend. Sie können mein Profil für weitere Informationen über mich überprüfen.
Beantworten Sie E-Mails automatisch mit Mail & AppleScript & Automator
AntwortenHierDatenschutz-Bestimmungen1y, 0v