Erstellen Sie eine neue (.txt) Datei im Finder - Tastaturkürzel

Nun, hier gehen Sie mit einem AppleScript dafür.

Erstellen Sie zuerst das AppleScript:

1. Automator öffnen
2. Erstellen Sie eine Schnellaktion
3. Setzen Sie den Eingang auf keinen Eingang
4. Ziehen Sie das Workflow-Element „AppleScript ausführen“ per Drag-and-Drop auf den grauen Bereich.
5. Fügen Sie den Code von unten in das AppleScript ein
6. Speichern Sie den Workflow als Neue Datei erstellen
   Wenn Sie iCloud Drive aktiviert haben, stellen Sie sicher, dass Sie die Datei unter Library/Services/in Ihrem Home-Ordner speichern.

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

So fügen Sie es als Verknüpfung hinzu:

• Gehen Sie zu Systemeinstellungen -> Tastatur -> Verknüpfungen -> Dienste
• Scrollen Sie nach unten, bis Sie die Service Create new-Datei finden
• Weisen Sie ihm eine Verknüpfung zu, indem Sie auf der rechten Seite auf none klicken , die sich in eine verwandelt Add Shortcut.
  Klicken Sie auf die Schaltfläche und geben Sie die Verknüpfung ein, die Sie verwenden möchten.
  Ich benutze ⌘ Command+ ⌥ Option+N

Ich habe ein AppleScript erstellt, das dem von @YoshiBotX sehr ähnlich ist, jedoch einige Verbesserungen aufweist.

Die Idee ist, einen Automator-Workflow zu erstellen und ihm mit den folgenden Schritten eine Verknüpfung zuzuweisen:

• Öffnen Sie Automator und erstellen Sie einen Dienst ;
• Setzen Sie die Eingabe auf keine Eingabe und die Anwendung auf Finder.app ;
• Ziehen Sie das Workflow-Element „AppleScript ausführen“ per Drag-and-Drop auf den grauen Bereich;
• Fügen Sie den Inhalt dieses AppleScripts in das Textfeld ein;
• Speichern Sie den Workflow unter einem sinnvollen Namen (z. B. New File );
• Gehen Sie zu Einstellungen -> Tastatur -> Kurzbefehle -> Dienste und weisen Sie ihm einen Kurzbefehl zu.

Lassen Sie uns nun das AppleScript zeigen:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Der Einfachheit halber füge ich dieses AppleScript in diesen GitHub Gist ein .

Sie können einem Skript auch eine Verknüpfung wie folgt zuweisen :

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

Der Einfügeort ist entweder das Ziel des vordersten Finder-Fensters oder der Desktop.

Sie können selbst einen Automator-Dienst erstellen – es ist ziemlich einfach. Dann können Sie ihm eine Tastenkombination zuweisen, damit Sie den Dienst nicht über das Dienstemenü aktivieren müssen (was Sie sowieso tun können).

Öffnen Sie Automator und wählen Sie Service als Typ des neuen Dokuments aus.

Stellen Sie den Dienst so ein, dass er keine Eingaben in Finder.app erhält, und fügen Sie die Aktion „Neues TextEdit-Dokument“ zum Workflow hinzu.

Speichern Sie den Dienst und öffnen Sie dann Systemeinstellungen → Tastatur → Verknüpfungen → Dienste, wo Sie den Dienst unter Allgemein mit dem Namen finden, den Sie ihm beim Speichern gegeben haben.

Fügen Sie dem Dienst eine Tastenkombination hinzu, indem Sie den Dienst auswählen und dann auf „Verknüpfung hinzufügen“ klicken.

Hier kann es zu Problemen kommen, wenn die Verknüpfung bereits verwendet wird. Seien Sie also kreativ, um eine zu erstellen, die für Sie funktioniert.

Terminal öffnen und eingeben

touch filename

oder

> filename

In den neuen macOS-Verknüpfungen können Sie den Code „AppleScript ausführen“ und den folgenden Code verwenden. Falls es bereits eine Datei mit demselben Namen gab, zeigt Ihnen Shortcuts eine eindeutige Ausführungsfehlermeldung, die für einen Endbenutzer lesbar ist.

on run {input, parameters}
    tell application "Finder"
        set selection to make new file at (get insertion location) with properties {name:"README.txt"}
    end tell
    return input
end run

Dies ist ein Repost eines Posts, den ich letztes Jahr gemacht habe. Mit folgendem habe ich gute Erfahrungen gemacht.

Es gibt zwei nützliche Dienstprogramme, die Sie herunterladen und installieren können, mit denen Sie eine neue Textdatei (oder RTF-Datei) in einem aktuell geöffneten Ordner erstellen können, den Sie mit dem Finder anzeigen.

Die Dienstprogramme heißen NewTextFileHere und NewRTFHere und können von heruntergeladen werden

http://mac.softpedia.com/developer/Jonas-Wisser-37498.html

Symbole für eine dieser Apps können dann in alle Ihre Finder-Fenster eingefügt werden.

Genau das, wonach ich gesucht habe, Richard Fuhr. Danke dafür.

Eine Anmerkung: Der Link dieser URL für NewTextFileHere scheint auf eine leere Seite geladen zu werden. Aber ich habe eine Suche durchgeführt und die App hier gefunden: http://mac.softpedia.com/progDownload/NewTextFileHere-Download-70374.html

Eine Alternative, wenn Sie bereits BetterTouchTools haben (es war früher eine kostenlose App, jetzt hat es ein Pay-what-you-want-Modell mit einer 30-tägigen Testphase), finden Sie die Aktion "Utility Actions > Create New File in Current Folder", die genau dies tut, mit a Pop-up, damit Sie den Namen auswählen können. Weisen Sie die gewünschte Verknüpfung zu (ich habe Option + Umschalt + N gewählt) und Sie können loslegen.

Falls Sie MacVim verwenden, gibt es unter eine Option Finder -> Serviceszum Erstellen eines neuen vim-Puffers:

Ich habe dies der Verknüpfung zugeordnet ShiftcmdMin System Preferences -> Keyboard -> Shortcuts: