Erstellen Sie einen Dienst mit Automator – Getestet auf macOS Sierra

1. Offen/Applications/Automator.app
2. Datei > Neu (cmd-N)
   • Wählen Sie einen Dokumenttyp aus: „Service“.
3. Dienst empfängt ausgewählt: "Dateien oder Ordner" im "Finder".
4. Navigieren Sie im linken Bereich zu: Aktionen > Bibliothek > Dienstprogramme > AppleScript ausführen.
   • Ziehen Sie das Element "AppleScript ausführen" aus dem Bibliotheksbereich auf der linken Seite in den Quellcodebereich auf der rechten Seite.
5. Löschen Sie den vorausgefüllten Inhalt vollständig. Fügen Sie den folgenden Quellcode ein:

AppleScript-Quellcode

use framework "Foundation" -- Cocoa-AppleScript

on run {input, parameters}
    repeat with thisItem in input
        tell application "Finder"
            if kind of thisItem is "Alias" then -- alias file only
                set parentPath to container of thisItem -- get the folder of this alias
                set {label index:l, comment:c, modification date:m, creation date:cr, original item:origPath, name:n} to properties of (item thisItem)
                if origPath is not missing value then -- not a breaking alias
                    set tagsList to (my tagsFor:(POSIX path of thisItem)) -- get the tags of the alias file (call an AppleScriptObjC handler)
                    delete thisItem -- move this alias to the trash

                    -- ** create an alias file **
                    set newAliasFile to make new alias at parentPath to origPath with properties {comment:c, creation date:cr, original item:origPath, name:n}
                    -- ** set the label ** (0 = no label)
                    if l is not 0 then set label index of newAliasFile to l
                    -- ** set  the tags ** ({} = no tag) 
                    if tagsList is not {} then (my setTags:tagsList forPath:(POSIX path of (newAliasFile as string))) -- call an AppleScriptObjC handler
                    -- ** change the modification date **
                    set modification date of newAliasFile to m
                end if
            end if
        end tell
    end repeat
end run

on tagsFor:posixPath -- Cocoa-AppleScript handler 
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    set {theResult, theTags} to fileURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- no tags
    return theTags as list
end tagsFor:

on setTags:tagList forPath:posixPath -- Cocoa-AppleScript handler
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    fileURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

6. Datei > Speichern (cmd-S): Geben Sie ihm einen Namen wie „Alias-Erstellung“.
7. Öffnen Sie Systemeinstellungen > Tastatur > Verknüpfungen > Dienste > Dateien und Ordner > Alias-Erstellung, oder wie auch immer Sie es benannt haben.
   • Weisen Sie ihm eine Verknüpfung zu. Da cmd-L verwendet wird, um einen Alias ​​​​zu erstellen (L wie in "link"), habe ich ihm cmd-alt-ctrl-L zugewiesen.
8. Wählen Sie eine oder mehrere Legacy-Aliasdateien aus und verarbeiten Sie sie.
   • Mit Ihrem Shortcut cmd-alt-ctrl-L.
   • oder über das Hauptmenü: Finder > Dienste > Dateien und Ordner > Alias-Erstellung.

Hinweis : Der Batch-Prozess ist sehr transparent und Fehler können korrigiert werden. Die gelöschten Aliase werden in Ihren Papierkorb verschoben. Sollten Sie einen Fehler gemacht haben, wählen Sie die betreffende Alias-Datei aus dem Papierkorb und führen Sie Finder > Put back (cmd-backspace) aus. Dadurch wird die Datei wieder in ihren vorherigen übergeordneten Ordner verschoben und der übergeordnete Ordner in einem neuen Fenster geöffnet. Dann hat man den neu erstellten Alias ​​und den Original-Alias ​​mit dem Zusatz „copy“ nebeneinander und kann ggf. Korrekturen vornehmen.