Erstellen Sie Wiedergabelisten für vollständige Alben in iTunes (dh Alben mit allen Titeln)

Mir wurde klar, dass dies eine Frage war, die kompliziert genug war, dass ich versuchen sollte, die Katze selbst zu häuten. Hier ist ein Ansatz:

-- Creates a playlist for each full album you have in iTunes
-- Set the playlistPrefix and playlistSuffix as desired before running

-- Based on code by Brad Campbell
-- http://www.bradcampbell.com/2009/05/26/make-a-whole-album-playlist-in-itunes/

tell application "iTunes"
    set playlistPrefix to "FA: "
    set playlistSuffix to ""
    -- The "FA: " prefix will help cluster full albums in iTunes' playlists,
    -- and is narrow enough to not get in your way when viewing on an iPhone

    set albumBuckets to {} as list
    set allSongs to (every track of library playlist 1 whose enabled is true and podcast is false and kind contains "audio") as list

    -- Find all partial albums in iTunes
    repeat with currentTrack in allSongs
        set albumName to album of currentTrack as text
        set artistName to artist of currentTrack as text

        -- First check for missing values, then perform integer comparison
        -- Zero is on the left to force interger type coercion, just in case
        if album of currentTrack is not missing value and 0 is less than length of albumName then
            if artist of currentTrack is not missing value and 0 is less than length of artistName then
                if track number of currentTrack is not missing value and 0 is less than track number of currentTrack then
                    if track count of currentTrack is not missing value and 0 is less than track count of currentTrack then
                        if albumBuckets does not contain album of currentTrack then
                            copy album of currentTrack to the end of albumBuckets
                        end if
                    end if
                end if
            end if
        end if

    end repeat

    repeat with currentAlbum in albumBuckets
        set albumSongs to (every track of library playlist 1 whose album is currentAlbum)
        set firstTrack to first item of albumSongs

        -- Filter album list to act only on full albums
        if (count of albumSongs) is equal to track count of first item of albumSongs and 1 is less than (count of albumSongs) then
            -- This is a full album, construct the playlist

            -- Sort tracks by track number
            set albumSongsSorted to {} as list
            repeat with i from 1 to (count of albumSongs)
                repeat with trk in albumSongs
                    if track number of trk is i then
                        set nextSong to trk
                        copy nextSong to the end of albumSongsSorted
                    end if
                end repeat
            end repeat

            -- Don't show artist name for compilations
            if firstTrack is not compilation then
                set playlistNameArtist to artist of firstTrack & " - "
            else
                set playlistNameArtist to ""
            end if

            set albumPlaylistName to playlistPrefix & playlistNameArtist & currentAlbum & playlistSuffix

            -- Create playlist
            if user playlist albumPlaylistName exists then
                try
                    delete tracks of user playlist albumPlaylistName
                end try
            else
                make new user playlist with properties {name:albumPlaylistName}
            end if

            try
                repeat with trk in albumSongsSorted
                    duplicate trk to user playlist albumPlaylistName
                end repeat
            end try
        end if
    end repeat

    display dialog "Playlists created! Check iTunes for playlists beginning with '" & playlistPrefix & "'"
end tell

Um dies auszuprobieren, kopieren Sie einfach den Codeblock, fügen Sie ihn in den AppleScript-Editor ein und drücken Sie auf Ausführen. Seien Sie sich bewusst, dass es keine einfache „Rückgängig“-Schaltfläche gibt – Sie müssen nur die Löschtaste gedrückt halten, wenn Sie alle erstellten Wiedergabelisten löschen möchten.

Es gibt wahrscheinlich einen schnelleren Algorithmus (dh einen, der nur einen einzigen Durchgang durch die iTunes-Bibliothek macht), aber ich konnte nicht herausfinden, wie man mit zweidimensionalen Variablen in AppleScript arbeitet, was eine Voraussetzung zu sein scheint.

Ein zusätzlicher Nebeneffekt dieses Skripts ist, dass es möglicherweise alte Alben in Ihrer Bibliothek aufdeckt, von denen Sie sich entfernt haben, und die Sie sicher löschen können :)