Ist es möglich, die ⌘-Verknüpfung von Chrome für den Hintergrund-Tab beizubehalten, während AppleScript verwendet wird, um die Erstellung eines neuen Tabs zu automatisieren?

Ich denke, das wird tun, was Sie fragen. Ich habe Ihren ursprünglichen Code geändert , um zu sehen, welcher Prozess zum Zeitpunkt der Ausführung am vordersten ist , um auf der Grundlage der in Ihrer Frage durch die Verwendung von * ausgedrückten Bedingungen entsprechend zu verzweigen und zu testen . um zu sehen, ob die Taste gedrückt wurde, als Google Chrome zum Zeitpunkt der Ausführung des Dienstes der vorderste Prozess war . * (Ich habe keine Verbindung zu Charles Poyntons Blog oder Stefan Kliemes checkModifierKeys, außer dass ich dieses Programm seit einigen Jahren ohne Probleme verwende.)checkModifierKeys⌘ command

Wie codiert geht es davon aus, dass sich das checkModifierKeysin befindet /usr/local/bin/. Ändern Sie nach Bedarf.

Siehe die Kommentare im if theFrontmostProcessWhenRun is "Google Chrome" then Block für seinen logischen Ablauf .

    on run {input, parameters}

        --  # Get the name of frontmost process at the time the services was run.
        --  #
        --  # This is used later in an if statement block for when if Google Chrome was frontmost process when run
        --  # to check that the value returned from checkModifierKeys was for the command key being pressed.

        tell application "System Events"
            set theFrontmostProcessWhenRun to get name of process 1 where frontmost is true
        end tell

        (*
    When triggering this Service in applications other than Google Chrome, such as TextEdit, the Chrome window opens in the background. This command brings the Chrome window to the foreground:
*)
        activate application "Google Chrome"

        (*
    Converting the selected text to plain text to remove any formatting:
        From: http://lifehacker.com/127683/clear-text-formatting-on-os-x
*)
        set selectedText to input
        set selectedText to (selectedText as text)

        (*
    Removing any line breaks and indentations in the selected text:
        From: http://stackoverflow.com/a/12546965 
*)

        set AppleScript's text item delimiters to {return & linefeed, return, linefeed, character id 8233, character id 8232}
        set plainTextSelectedText to text items of (selectedText as text)
        set AppleScript's text item delimiters to {" "}
        set plainTextSelectedText to plainTextSelectedText as text

        (* Assigning variables: *)
        set baseURL to "https://www.google.com/search?q="
        set finalLink to baseURL & plainTextSelectedText

        (* Opening webpage in Chrome: *)
        (*
    The following tell block creates a new tab, located immediately after the currently open tab, which is what I want to occur.
        From: http://apple.stackexchange.com/questions/271702/applescript-how-to-open-a-link-in-google-chrome-in-a-new-adjacent-tab/271709#271709
*)


        if theFrontmostProcessWhenRun is "Google Chrome" then
            --  # Google Chrome was the frontmost process when the service was run.
            if ((do shell script "/usr/local/bin/checkModifierKeys") as integer) is equal to 256 then
                --  # The command key was pressed when the service was run.
                tell application "Google Chrome"
                    --  # See Note: below.
                    set activeTab to active tab index of front window
                    tell front window to make new tab at after (get active tab) with properties {URL:finalLink} -- open a new tab after the current tab
                    set active tab index of front window to activeTab
                end tell
            else
                tell application "Google Chrome"
                    tell front window to make new tab at after (get active tab) with properties {URL:finalLink} -- open a new tab after the current tab
                end tell
            end if
        else
            --  # Google Chrome was not the frontmost process when the service was run.
            tell application "Google Chrome"
                tell front window to make new tab at after (get active tab) with properties {URL:finalLink} -- open a new tab after the current tab
            end tell
        end if

    end run

Hinweis: Wenn Google Chrome zum Zeitpunkt der Ausführung des Dienstes im Vordergrund steht und die Taste gedrückt wird, erhält dies den aktuellen und setzt ihn nach dem Erstellen des neuen Tabs wieder darauf zurück . Dies ist als Problemumgehung gedacht, da es etwas klobig ist, aber besser als nichts, bis eine elegantere Lösung für ein Problem gefunden werden kann.⌘ commandactive tab index