Rechtsklick zum Erstellen eines neuen Dokuments - wie?

Hier ist ein AppleScript , das ich als AppleScript - Anwendung verwende, damit ich ihm das TextEdit - Symbol zuweisen und es in der Symbolleiste von Finder platzieren kann . Dann ist es möglich, ein neues Textdokument an einem beliebigen Ort zu erstellen, auf den der Finder eingestellt ist, auf den man Schreibberechtigungen hat. Mit anderen Worten, wenn man versucht, ein neues Textdokument an einer Stelle zu erstellen, für die zB nur Schreibzugriff besteht, rootoder an irgendeiner Stelle, für die man keine speziellen Schreibberechtigungen hat, dann wird man benachrichtigt, wenn man versucht, das neue Textdokument zu erstellen.

Der Code überprüft, ob bereits eine Datei mit demselben Namen vorhanden ist, und meldet dies, wenn dies der Fall ist, und bringt das Dialogfeld „ Speichern unter: “ zurück .

Öffnen Sie den (Apple)Script Editor und kopieren Sie den folgenden Code , fügen Sie ihn in das leere Fenster ein und speichern Sie ihn als Create New Text File Here.app . Stellen Sie sicher, dass Sie Application for File Format: im Dialogfeld Save As: auswählen .

Bevor Sie es zur Symbolleiste von Finder hinzufügen , sollten Sie sein Symbol in das ändern, das von TextEdit verwendet wird . Sie können das Blatt "Informationen abrufen" für jede App öffnen und dann das Blatt aus TextEdit.app in das Blatt in Create New Text File Here.app kopieren und einfügen . Beachten Sie, dass dies das Symbol ist, das in der oberen linken Ecke des Fensters „Informationen abrufen“ angezeigt wird .

Jetzt, da es ein schöneres Symbol hat, ziehen Sie die neue App per Drag & Drop an die Stelle in der Symbolleiste von Finder , an der Sie sie haben möchten. Beachten Sie, dass Sie je nach Version von OS X/macOS möglicherweise die Befehlstaste ⌘ drücken müssen, während Sie die App in die Symbolleiste von Finder ziehen .

Klicken Sie zur Verwendung einfach auf das Symbol „Create New Text File Here.app“ in der Symbolleiste des Finder und Sie werden aufgefordert, einen Namen einzugeben, und eine neue Textdokumentdatei wird erstellt und am aktuellen Speicherort des Finder - Fensters geöffnet .

on run
    my createNewTextFile()
end run


on createNewTextFile()

    tell application "Finder"
        activate
        set the currentFolder to (folder of the front window as alias)
    end tell

    tell me
        activate
        set fileName to ""
        repeat while fileName = ""
            display dialog "Save As:" with title "Create New Text File Here" default answer fileName buttons {"Cancel", "OK"} default button 2
            set fileName to text returned of the result
        end repeat
        if fileName ends with ".txt" then
            set newTextFile to POSIX path of currentFolder & fileName
        else
            set newTextFile to POSIX path of currentFolder & fileName & ".txt"
        end if

    end tell

    tell application "Finder"
        set itExists to (exists newTextFile as POSIX file)
    end tell

    tell me
        activate
        if itExists is false then
            try
                do shell script "touch \"" & newTextFile & "\"; open \"" & newTextFile & "\""
            on error
                display dialog "Cannot create the \"" & newTextFile & "\" file at this location!..." with title "Cannot Create File" buttons {"OK"} default button 1 with icon stop
            end try
        else
            display dialog "The \"" & newTextFile & "\" file already exists!..." with title "File Already Exists" buttons {"OK"} default button 1 giving up after 5
            my createNewTextFile()
        end if
    end tell

end createNewTextFile

Beachten Sie, dass dieser Code auch in Automator für einen Service-Workflow verwendet werden könnte , aber ich habe festgestellt, dass ich bereits im Finder bin , wenn ich ein neues Textdokument erstellen möchte, und es einfach einfacher ist, auf die App Create New Text File Here.app zu klicken Symbol in der Symbolleiste von Finder , dann mit der rechten Maustaste klicken und aus dem bereits überfüllten Dienste - Kontextmenü auswählen , das ich habe.

Wenn Sie den Code ändern, nachdem das Skript als Anwendung gespeichert und in der Symbolleiste von Finder platziert wurde, müssen Sie außerdem das Symbol aus der Symbolleiste entfernen und dann die neu gespeicherte Create New Text File Here.app ziehen und ablegen damit es richtig funktioniert.

Ich habe ein Skript, das ich im Finder mit einer Tastenkombination von FastScripts ( ⇧⌃⌘N) ausführe, das eine Auswahlliste mit Dateivorlagen (in einem Vorlagenordner gespeichert) anzeigt. Um neue Vorlagen hinzuzufügen, platzieren Sie sie einfach in diesem Ordner.

Vor ein paar Jahren auf StackExchange gepostet: How to create a text file in a folder

-ccs

Ich habe das Menü „Neue Datei“ aus dem Mac App Store verwendet, um neue Dateien per Rechtsklick zu erstellen, und es funktioniert einwandfrei. Es enthält etwa 30 Vorlagen, aber Sie können auch Ihre eigenen erstellen. Scheint eine viel einfachere Lösung zu sein.

Informationen dazu finden Sie unter https://langui.net/new-file-menu/ & unter https://itunes.apple.com/us/app/new-file-menu/id1064959555?mt=12 .