Wie finde ich doppelte benachbarte Zellen in Numbers?

Ich habe ein Numbers-Blatt, das Tausende von Zeilen lang ist. Als Beispiel im Bild hat das Blatt zwei Spalten mit URLs. Was ich tun muss, ist, die Zeilen zu finden, die dieselbe URL in den zwei angrenzenden Zellen haben, und dann die Hintergrundfarbe dieser Zeile zu ändern, damit ich die Zeilen identifizieren und löschen kann; oder schreiben Sie das Wort „dupe“ in Spalte C. In unserem Beispiel hat Zeile 4 dieselbe URL wie die beiden Zellen. Wie würde ich solche Zeilen im gesamten Blatt kennzeichnen oder markieren? Mit einer Rechnung? Oder ein Applescript/Automator?

Geben Sie hier die Bildbeschreibung ein

Wenn dies eine einmalige Sache ist und basierend auf dem Bild in Ihrer Frage, würde ich einfach IF(A2=B2,"DUPE","")als neue Formel in C2 einfügen ... dann drücken Sie bei ausgewähltem C2 Befehlstaste-C, um die Formel zu kopieren ... und scrollen Sie dann nach unten zu letzte Zeile mit Informationen und drücken Sie die Umschalttaste, während Sie auf die letzte Zelle in Spalte C klicken, um den Bereich auszuwählen, und drücken Sie Strg-C, um die Formel einzufügen. Nun, da Spalte C gegebenenfalls „DUPE“ enthält, würde ich das Blatt in Spalte C sortieren und die Zeilen mit „DUPE“ darin markieren und löschen. Wählen Sie dann Spalte C aus und drücken Sie die Entf-Taste, um die Formel zu entfernen.
Das hätte Control-V sein sollen, um die Formel einzufügen. (Das bekomme ich beim Kopieren und Einfügen.)
Danke, das sollte funktionieren, aber ich bekomme nur die Formel in jeder Zelle in Spalte C und sie berechnen nicht.
Sie sagten: "Das sollte funktionieren, aber alles, was ich bekomme, ist die Formel in jeder Zelle in Spalte C und sie werden nicht berechnet". Das liegt daran, dass Sie sie nicht richtig kopieren, nachdem Sie Zahlen> Einfügen> Formel> Neue Formel und Einfügen verwendet haben die Formel in der Zelle, in die Sie die Eingabetaste drücken, wählen Sie dann die Zelle erneut aus, in die Sie die Formel eingefügt haben, und drücken Sie dann Befehlstaste-C, um sie zu kopieren. Mit anderen Worten, das Formelfenster sollte nicht geöffnet sein, wenn Sie die Kopie nach dem ursprünglichen Einfügen erstellen.

Antworten (1)

Hier ist eine AppleScript-Methode, die drei verschiedene Arten von Aktionen zeigt, die auf die Zeilen mit doppelten Zelleneinträgen in columns "A"und "B"(äquivalent zu cells 1and 2) angewendet werden:

use N : application "Numbers"
--------------------------------------------------------------------------------
# PROPERTY VALUES & GLOBAL VARIABLES
property document : a reference to document 1 of N
property sheet : a reference to active sheet of my document
property table : a reference to table 1 of my sheet

global them
--------------------------------------------------------------------------------
# IMPLEMENTATION:
on run
    if not (exists my table) then return false

    set them to a reference to (every row of my table ¬
        where the value of cell 1 = the value of cell 2 ¬
        and the value of cell 1 ≠ missing value)

    highlight()
    ---OR:
    -- comment()
    --OR:
    -- delete -- WARNING: permanent!
end run
--------------------------------------------------------------------------------
# HANDLERS:
to highlight()
    set the background color of them to ¬
        {65535, 65535 / 4, 65535 / 2}
end highlight

to delete
    delete them
end delete

to comment()
    set the value of cell 3 of them to "SNAP!"
end comment
---------------------------------------------------------------------------❮END❯

Ich habe drei Handler definiert, highlight(), comment()und delete, von denen jeder, wenn er aufgerufen wird, eine bestimmte Aktion für die interessierenden Zeilen ausführt. Derzeit können Sie im Skript einige Zeilen innerhalb des Abschnitts mit der Bezeichnung sehen, IMPLEMENTATION:dass ich es derzeit so eingestellt habe, dass es die Aktion ausführt highlight(), wodurch die Hintergrundfarbe der bestimmten Zeilen in einen Rosaton geändert wird, den ich mag.

Unter dieser Zeile befinden sich Befehle, die ich mit auskommentiert habe --, sodass sie derzeit inaktiv bleiben. Wenn es nicht kommentiert ist, comment()gibt der Handler das Wort "SNAP!"in die dritte Spalte jeder interessierenden Zeile ein; und der deleteBefehl (beachten Sie das Fehlen von Klammern für diesen) löscht einfach die Zeilen vollständig. Ich habe dies mit einer Warnung markiert, die eine dauerhafte Löschung impliziert, obwohl Sie die Zeilen in Wahrheit mit dem integrierten Menüelement „ Rückgängig“⌘Z der Anwendung oder (einzeln!)

Schöner Rosaton! :) +1
Danke, das funktioniert super und ist ein gutes Beispiel für die Arbeit mit Numbers.
Wie finde ich doppelte benachbarte Zellen in Numbers?
AntwortenHierDatenschutz-Bestimmungen1y, 0v