Ich navigiere zu einem Ordner und erweitere dann einen Verzeichnisbaum, um die gesuchte Datei zu finden. Jetzt möchte ich einen Ordner an der aktuellen Position innerhalb dieses Baums erstellen.
Vereinfachtes Beispiel (danke soulshined):
/Users/user/Downloads/
/Users/user/Downloads/Pictures
/Users/user/Downloads/Pictures/pic1.jpg
/Users/user/Downloads/Pictures/pic2.jpg
/Users/user/Downloads/Pictures/pic3.jpg
/Users/user/Downloads/Pictures/pic4.jpg
/Users/user/Downloads/Pictures/pic5.jpg
Das Finder-Fenster wird im /Users/user/Downloads
Verzeichnis geöffnet, aber ich habe die Tree-Expander verwendet, um die Dateien in .../Downloads/Pictures
.
Ich möchte einen Ordner unter hinzufügen Pictures
, aber unabhängig davon, wie ich ihn aufrufe, wird das neue Verzeichnis immer unter erstellt Downloads
.
(Natürlich wäre es in diesem Beispiel trivial, ihn zu verschieben, aber stellen Sie sich vor, der Ordner ist ein byzantinischer Unternehmensverzeichnisbaum, ...)
Ich denke, der Schlüssel hier ist: Sie müssen zuerst auf das Verzeichnis doppelklicken, in dem Sie den neuen Ordner erstellen möchten.
Wenn Sie Datei-> Neuer Ordner (oder Umschalt-Befehl-N) auswählen, wird kein neuer Ordner im aktuellen Ordner erstellt (oder zumindest in dem, was ich als den aktuellen Ordner betrachten würde).
Zum Beispiel würde ich im angehängten Bild erwarten, dass "Neuer Ordner" einen neuen Ordner in Ordner1 (ausgewählt) erstellt - stattdessen wird er im Ordner "Gast" erstellt - dem ursprünglich geöffneten Ordner.
Um es in Ordner1 zu erstellen, müssen Sie zuerst auf Ordner1 doppelklicken.
Öffnen Sie den Ordner, in dem Sie einen neuen Ordner erstellen möchten, und dann Datei > Neuer Ordner oder Umschalt-Befehl-N.
ODER
Sie müssen zuerst auf das Verzeichnis doppelklicken, in dem Sie den neuen Ordner erstellen möchten. Sobald Sie drinnen sind, klicken Sie mit der rechten Maustaste und wählen Sie "Neues Verzeichnis".
So erstelle ich einen neuen Ordner im Finder (Listenansicht) nur mit der Tastatur:
Unter Windows + Total Commander musste ich nur F7die Taste drücken, um einen neuen Ordner zu erstellen :)
Ab OSX Catalina,
CommandShiftNErstellt einen neuen Ordner innerhalb des Ordners innerhalb des geöffneten Fensters (in Ihrem Beispiel das ~/Downloads
Verzeichnis). Datei > Neuer Ordner, das Kontextmenü und das Menü Aktionen (Zahnrad) haben das gleiche Verhalten, unabhängig davon, was ausgewählt ist.
Dies ist meiner Erfahrung nach nicht mit Pre-Catalina vereinbar. Ich weiß nicht, warum sich das geändert hat. Die einzige Methode besteht darin, zuerst auf das Verzeichnis zu doppelklicken Pictures
.
Das Problem besteht darin, dass die Listenansicht den Inhalt mehrerer Ordner gleichzeitig anzeigt, sich aber nur im Ordner der obersten Ebene befindet, der in der Titelleiste aufgeführt ist. Der Befehl „Neuer Ordner“ verhält sich aus Gründen der Konsistenz genauso wie in anderen Ansichten. (Das ist Apples Meinung dazu, ob Sie damit einverstanden sind oder nicht.)
Für diejenigen, die es möchten, habe ich eine sehr einfache Automator-Schnellaktion erstellt, die zu funktionieren scheint, wenn Sie mit der rechten Maustaste auf einen Ordner in der Listenansicht klicken.
on run {input, parameters}
tell application "Finder"
set thefolder to (input as text)
make new folder at thefolder with properties {name:"New Folder"}
end tell
return input
end run
Im Finder gibt es dafür keine integrierte Möglichkeit (ab macOS 12 Monterey, 2021), aber Sie können stattdessen eine benutzerdefinierte Automator-Aktion erstellen. Dadurch wird ein Rechtsklick-Menüelement sowie eine Tastenkombination bereitgestellt, um einen Ordner unter dem ausgewählten Ordner im Finder zu erstellen. (Diese Antwort baut auf der hervorragenden Antwort von Benwiggy auf, indem eine Dialogaufforderung, eine Tastenkombination hinzugefügt und der neue Ordner erweitert/ausgewählt wird.)
Starten Sie Automator
und klicken Sie auf Datei > Neu
WählenQuick Action
Wählen Sie auf der rechten Seite „Workflow erhält Strom: folders
in Finder.app
“
Wählen Sie im linken Bereich Library > Utilities > Run Applescript
. Ziehen Sie Run Applescript
in das rechte Feld.
Kopieren Sie den folgenden Code und fügen Sie ihn ein:
on run {input, parameters}
set SELECTED_FOLDER to (input as text)
# prompt for new folder name
set NEW_FOLDER_NAME to text returned of (display dialog "Name of new folder?" buttons {"Cancel", "OK"} default button "OK" default answer "")
delay 0.1 # prevent UI race conditions
# create new folder
tell application "Finder"
set NEW_FOLDER to make new folder at SELECTED_FOLDER with properties {name:NEW_FOLDER_NAME}
end tell
# expand new folder
tell application "Finder"
set selection to SELECTED_FOLDER
activate # need to activate before sending keystroke
end tell
tell application "System Events"
# requires System Preferences > Security & Privacy > Privacy > Accessibility: add Finder.app
key code 124 # right arrow to expand folder
delay 0.1 # prevent UI race conditions
end tell
# select new folder
tell application "Finder"
set selection to NEW_FOLDER
end tell
return input
end run
Klicken Sie auf die Schaltfläche "Hammer", um zu kompilieren und Syntaxhervorhebung zu erhalten.
Datei > Speichern. Benennen Sie das Skript create new folder here.workflow
oder was auch immer Sie wollen.
Fügen Sie nun eine Tastenkombination für die soeben erstellte Schnellaktion hinzu:
OffenPreferences > Keyboard > Services > Files and Folders
Sie sollten das aufgelistete Element sehen create new folder here
.
Klicken Sie auf Add Shortcut
und weisen Sie die Tastenkombination cmd+shift+M
oder was auch immer Sie möchten zu.
cmd+shift+opt+N
da das einfach opt
plus war cmd+shift+N
, die integrierte Tastenkombination für Finder New Folder
. Aber diese Verknüpfung funktionierte aus irgendeinem Grund nicht, es piepte nur. Also wählte ich cmd+shift+M
, da es neben war cmd+shift+N
.Dies ist erforderlich, da zum Erweitern des Finder-Ordners der right arrow
Tastendruck gesendet werden muss, was zusätzliche Berechtigungen erfordert.
OffenSystem Preferences > Security & Privacy > Privacy > Accessibility
"Finder.app" hinzufügen ( /System/Library/CoreServices/Finder.app
)
Stellen Sie sicher, Finder.app
dass überprüft wird.
System Settings > Keyboard > Keyboard Shortcuts > Services > Files and Folders
, und es gibt kein „Verknüpfung hinzufügen“ unten (doppelklicken Sie einfach auf „keine“). Berechtigungen sind vorhanden System Settings > Privacy & Security > Accessibility
, obwohl ich trotzdem aufgefordert wurde, Berechtigungen bei der ersten Ausführung zu erteilen. Und schließlich erhalte ich auch nur einen Signalton bei der Ausführung , wenn ich es versuche cmd+shift+opt+N
, und wenn Sie etwas festlegen, das bereits zugewiesen ist, wird stattdessen die vorhandene Aktion ausgeführt, was cmd+shift+M
eine gute Wahl ist.Hier ist ein Skript, das Sie dafür verwenden können. Es funktioniert sowohl in Listen- als auch in Spaltenansichten. Der Umbenennungsteil funktioniert in Symbol- und Galerieansichten nicht richtig, was ärgerlich sein kann.
Um es mit einer Verknüpfung zu verwenden, habe ich es als Anwendung aus dem Skripteditor exportiert und eine Verknüpfung zu dieser Anwendung in Butler festgelegt . Ich habe die Standard-Finder-Verknüpfung für „Neuer Ordner“ verwendet, da ich keine Symbol- und Galerieansichten benötige, aber Sie möchten vielleicht etwas anderes, um weiterhin die normale Verknüpfung verwenden zu können. Beachten Sie, dass der App Zugriffsberechtigungen erteilt werden müssen (Systemeinstellungen › Sicherheit › Vertraulichkeit).
Möglicherweise möchten Sie die Verzögerungen an die Reaktionsfähigkeit Ihres Systems anpassen, da sie lästig sein können, wenn Sie daran gewöhnt sind, den Namen des neuen Ordners schnell einzugeben, nachdem er erstellt wurde. Wenn sie jedoch zu niedrig sind, funktioniert das Umbenennen nicht.
-- By Philippe-André Lorin
-- 2020-12-13
-- macOS 10.14.4
-- See https://apple.stackexchange.com/a/408759/185198
-- Create folder inside currently selected folder
-- or at the same level as currently selected file
try
tell application "Finder"
set selectedItems to selection
set currentPath to ((the first item of the selectedItems) as alias)
-- Set parent path for future new folder
if (currentPath as string) ends with ":" then
-- It’s a folder
set the parentPath to currentPath
else
-- It’s a file
set {savedDelimiters, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ":"}
set the parentPath to (text items 1 thru -2 of (currentPath as string)) as string
set AppleScript's text item delimiters to savedDelimiters
end if
-- Create new folder
my createFolder(parentPath)
end tell
on error -- No folder or file is selected
tell application "Finder"
set the currentPath to (folder of the front window as alias)
my createFolder(currentPath)
end tell
end try
on createFolder(folderLocation)
tell application "Finder"
-- Make new folder
set thisFolder to make new folder at folderLocation
delay 0.2 -- N.B. Without delays, the following operations sometimes fail.
-- Select new folder
set selection to thisFolder
delay 0.2
-- Call “Rename” menu in Finder
activate
tell application "System Events"
tell application "System Events"
tell process "Finder"
tell menu bar 1
-- N.B. The following must be adjusted to the Finder’s language settings
tell menu bar item "File"
tell menu "File"
click menu item "Rename"
end tell
end tell
end tell
end tell
end tell
end tell
-- Return
return thisFolder
end tell
end createFolder
Notiz. Dieses Skript wurde vom ersten Skript auf dieser Seite angepasst: http://hints.macworld.com/article.php?story=20081119025327978
Seelenglanz
Philippe-André Lorin
Heide Raftery