Wie öffne ich einen Link in einem bestimmten Safari-Fenster in macOS?

Dies kann mit einer AppleScript-App erfolgen, die den Link in Safari öffnet und diese App zum Standardbrowser macht.

Ich habe beim Testen zwei Versionen gefunden: entweder in neuen Fenstern oder in neuen Tabs öffnen, wenn sich bereits ein Fenster im aktuellen Bereich befindet.

• Öffnen Sie Script Editor.app (oder noch besser Script Debugger)

• Wenn Sie möchten, dass Links in einem neuen Fenster geöffnet werden , verwenden Sie dies

    on open location theURL    
        tell application "Safari"  
            make new document with properties {URL:theURL}  
            activate  
        end tell  
    end open location  

• Wenn Sie möchten, dass Links in einem neuen Tab geöffnet werden (wenn im aktuellen Bereich ein Fenster verfügbar ist), verwenden Sie Folgendes:

    on open location theURL  
        tell application "System Events"  
            tell process "Safari"  
                try  
                    set frontWinName to name of window 1 
                on error  
                    my openNewWindow(theURL)  
                    return  
                end try  
            end tell  
        end tell  

        tell application "Safari"  
            try  
                tell (first window whose name is frontWinName and miniaturized is false)  
                    set current tab to make new tab with properties {URL:theURL}  
                    activate  
                end tell  
            on error  
                my openNewWindow(theURL)  
            end try  
        end tell  
    end open location  


    on openNewWindow(theURL)  
        tell application "Safari"  
            make new document with properties {URL:theURL}  
            activate  
        end tell  
    end openNewWindow  

• Als App speichern

• Wenn Sie nicht möchten, dass die App im Dock angezeigt wird

  • Klicken Sie mit der rechten Maustaste auf die App, gehen Sie in das Paket und suchen SieInfo.plist

  • Fügen Sie dies hinzuInfo.plist

      <key>LSUIElement</key>  
      <true/>
  

• Legen Sie die App als Standardbrowser fest (ich habe RCDefaultApp verwendet).

Wenn Sie sehen möchten, wie nervig das standardmäßige Verbindungsverhalten von macOS ist, schlage ich vor, nach einigen Stunden wieder auf Safari als Standardbrowser umzuschalten ...

Ich bin immer noch am 10.14.6 und kenne mögliche Einschränkungen in Catalina nicht.

Als Entwickler habe ich die Möglichkeit untersucht, dass Erweiterungen das erreichen können, was Sie wollen, indem immer ein neues Fenster geöffnet wird, wenn Sie auf einen Link klicken, der außerhalb von Safari selbst enthalten ist. Es tut mir leid zu sagen, dass ich nicht glaube, dass dieser Ansatz möglich sein wird.

Leider bietet Safari Erweiterungen keine Möglichkeit, den Ursprung eines neuen Tabs/Fensters zu bestimmen. Was ich damit meine, ist, dass ein neuer Tab erstellt werden kann, weil der Benutzer auf einen Link in einer E-Mail klickt, mit der Befehlstaste auf einen Link in Safari klickt, ein Safari-Lesezeichen öffnet, während er die Befehlstaste gedrückt hält, auf einen Link in einem PDF-Dokument klickt oder irgendetwas anderes eine von mehreren anderen Aktionen, die eine Seite in einem neuen Tab öffnen. Unabhängig von der Methode stellt Safari einer Safari-Erweiterung nicht bereit , wie das Fenster geöffnet wurde.

Da alle diese Ereignisse gleich aussehen, kann keine Erweiterung Links von außerhalb von Safari dazu zwingen, sich in neuen Fenstern zu öffnen, ohne auch Links zu beeinflussen, die auf andere Weise geöffnet werden (einschließlich beim Surfen in Safari).

Obwohl es nicht nativ in Ihrem gewünschten Fenster geöffnet wird, können Sie jederzeit die Registerkarte greifen und sie direkt nach dem Öffnen in einem anderen Safari-Fenster neu positionieren.

Keine Ahnung, ob das hilft oder nicht, nur ein Vorschlag.