Alias ​​- 'Original anzeigen' in neuem Tab

Ich sah mich um und fand ein Applescript (das in eine Verknüpfung umgewandelt werden kann), das genau das will, was Sie wollen. Leider ist es nicht super einfach, wie es sein sollte. Es ist jedoch besser als nichts, und Sie müssen dies nur einmal tun. Es wird Ihnen auf lange Sicht Zeit sparen.

1) Öffnen Sie Automator.

2) Neuen 'Dienst' erstellen

3) Stellen Sie Service Receives auf 'no input' in 'Finder' ein

4) fügen Sie 'Applescript ausführen' hinzu

5) Fügen Sie diesen Code darin ein:

-- duplicateFinderTab.scpt
-- Uses a hacky workaroud to duplicate the frontmost Finder tab,
-- since Apple hasn't provided great AppleScript support for this.

----------------------------------------------
on run {}
    tell application "Finder"
        if (count of Finder windows) > 0 then set duplicate_me to target of front Finder window
        set _sel to the selection
    end tell

    new_tab()

    tell application "Finder"
        set target of front Finder window to duplicate_me
        select _sel
    end tell

    open_orig()

end run

----------------------------------------------
on new_tab()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "New Tab"
            perform action "AXPress"
        end tell
    end tell
end new_tab
----------------------------------------------
on open_orig()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "Show Original"
            perform action "AXPress"
        end tell
    end tell
end open_orig

6) Speichern Sie es (wenn Sie ein Finder-Fenster öffnen und Ihren Alias ​​ausgewählt haben, gehen Sie dann zurück zu Automator und klicken Sie auf „Ausführen“, dann funktioniert es an dieser Stelle) – Hinweis: Sie werden möglicherweise aufgefordert, „Automator“ hinzuzufügen. zu den 'Systemeinstellungen' -> 'Sicherheit & Datenschutz' -> 'Barrierefreiheit'-Berechtigungen.

7) Gehen Sie in den Systemeinstellungen zu 'Tastatur' -> 'Verknüpfungen' -> 'Dienste' -> 'wie auch immer Sie es genannt haben' .. wählen Sie eine Verknüpfung (wie "^-CMD-O").

Andere Dinge:

Möglicherweise müssen Sie dies einmal tun:

wenn finder ausgewählt ist, im menü,

'Finder' -> 'Dienste' -> 'wie auch immer Sie es genannt haben'

oder wenn es nicht erschienen ist:

'Finder' -> 'Dienste' -> 'Diensteeinstellungen...' -> Aktivieren Sie das Kontrollkästchen in den Systemeinstellungen, dass Ihre Anwendung aufgerufen wird

Es gibt andere Berechtigungsfehler, die Sie möglicherweise erhalten, je nachdem, wie Ihr System eingerichtet ist. Sie sollten jedoch feststellen, dass das Skript funktioniert, wenn Sie in Schritt 6 oder nach Schritt 5 auf „Ausführen“ klicken. Wählen Sie dann einfach zuerst die Datei im Finder aus Wechseln Sie zur Automator-App und klicken Sie auf „Ausführen“.

Und wenn alles für Sie reibungslos funktioniert hat, sollte die Verknüpfung cmd-cntl-O für Sie funktionieren, damit Sie diese Verknüpfung ausführen können (die eine neue Registerkarte mit derselben Auswahl öffnet), dann mit der rechten Maustaste klicken und „Original anzeigen“ auswählen.

Bearbeiten durch OP
Wenn Sie die Fehlermeldung "com.automator.runner.xpc ist kein unterstützender Zugriff zulässig" erhalten, ist die Problemumgehung nicht offensichtlich.
Sie können com.automator.runner.xpc selbst nicht zu Assistive Access hinzufügen, noch hilft das Hinzufügen von Automator oder Automator Runner, aber nach einem Neustart war der Hinweis, dass zwei Fehler ausgelöst wurden, nicht nur einer.

Durch das Hinzufügen von Finder selbst zu Assistive Access konnte das Skript ausgeführt werden.

Eine viel kürzere und sauberere Lösung ohne UI-Scripting:

Öffnen Sie Automator, erstellen Sie einen neuen Dienst, akzeptieren Sie Dateien und Ordner aus dem Finder, fügen Sie eine Run AppleScript- Aktion hinzu und geben Sie Folgendes ein:

on run {input, parameters}
    repeat with aFile in input
        tell application "Finder"
            try
                set origFile to original item of aFile
                set aWindow to make new Finder window
                set aWindow's target to origFile's parent
                select origFile
            end try
        end tell
    end repeat
end run

Ihr Bildschirm sollte in etwa so aussehen:

Speichern Sie den Automator-Dienst als In neuem Fenster anzeigen und öffnen Sie dann Systemeinstellungen/Tastatur/Kurzbefehle/Dienste . Suchen Sie den Dienst In neuem Fenster anzeigen , klicken Sie auf Verknüpfung hinzufügen und geben Sie ein ⌥⌘R. Ihr Bildschirm sollte in etwa so aussehen:

Schließen Sie den Dienst und versuchen Sie es im Finder, indem Sie einen oder mehrere Aliasnamen auswählen und auf die gewählte Verknüpfung drücken ⌥⌘R. Es funktioniert mit mehreren Dateien, Ordnern und kann das Reveal durchführen, selbst wenn einige der Elemente keine eigentlichen Aliase sind (daher das try/end try im Skript).

Mit Hilfe von StackOverflow und ausgehend von den Ideen, die in beiden Antworten von brw59 boris42 präsentiert wurden , habe ich dies jetzt von user3439894

on run {input, parameters}
    set madeNewWindow to false
    repeat with i from 1 to count input
        tell application "Finder"
            if (kind of item i of input) is equal to "Alias" then
                set origFile to original item of item i of input
                if not madeNewWindow then
                    set aWindow to make new Finder window
                    set madeNewWindow to true
                else
                    my makeNewTab()
                end if
                set aWindow's target to origFile's parent
                select origFile
            end if
        end tell
    end repeat
end run

on makeNewTab()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "New Tab"
            perform action "AXPress"
        end tell
    end tell
end makeNewTab

Es kombiniert das, was ich zu brauchen dachte , mit dem, was ich tatsächlich brauchte, indem es sowohl UI- als auch Nicht-UI-Scripting verwendet und mir ein neues Fenster präsentiert, das schön mit Registerkarten gefüllt ist, alle mit einem ausgewählten Alias, sodass ich durch die Registerkarten blättern und damit umgehen kann jede Auswahl einzeln, dann schließen Sie danach und lassen mein ursprüngliches Fenster an Ort und Stelle.