AppleScript-Fortschrittsbalken-Fehler: Wie kann verhindert werden, dass der Fortschrittsdialog verweilt?

Funktioniert für mich auf der neuesten Version von macOS Big Sur

AKTUALISIEREN

BESTE LÖSUNG

Wenn Sie den display dialogBefehl innerhalb von platzieren und den Befehl dann um diesen Befehl System Events tell blockwickeln , führt der seine Aufgabe aus, ohne darauf zu warten, dass das Fenster geschlossen wird.ignoring application responsesdisplay dialogprogress indicatordisplay dialog

Der ignoring application responsesBefehl funktioniert nur, wenn er innerhalb einer Anwendung platziert wirdtell block

set n to 50

set progress total steps to n
set progress description to "Script Progress"
set progress additional description to "Additional description"

repeat with i from 1 to n
    delay 0.1
    set progress completed steps to i
end repeat

tell application "System Events"
    activate
    ignoring application responses
        display dialog "The progress dialog should be gone at this point."
    end ignoring
end tell

ALTE LÖSUNG 1

set n to 5

set progress total steps to n
set progress description to "Script Progress"
set progress additional description to "Additional description"

repeat with i from 1 to n
    delay 0.1
    set progress completed steps to i
end repeat
return
quit

on quit
    activate
    display dialog "The progress dialog should be gone at this point."
    continue quit -- allows the script to quit
end quit

Hier ist eine Möglichkeit, einige Wiederholungsschleifen auszuführen, bevor das Skript beendet wird

set n to 5

set progress total steps to n
set progress description to "Script Progress"
set progress additional description to "Additional description"

repeat with i from 1 to n
    delay 0.1
    set progress completed steps to i
end repeat
return
quit

on quit
    activate
    display dialog "The progress dialog should be gone at this point."
    repeat 5 times
        my get_my_IP()
        my screenCaptureToDesktop()
        delay 1
    end repeat
    continue quit -- allows the script to quit
end quit


on get_my_IP()
    activate
    tell current application to display dialog (do shell script "curl ifconfig.co") with icon 2 buttons "OK" default button 1 with title "Your Current IP Address Is.." giving up after 5 -- "curl ifconfig.io"    -- alternate
end get_my_IP

on screenCaptureToDesktop()
    do shell script "/usr/sbin/screencapture \"" & ¬
        POSIX path of (path to desktop as string) & ¬
        "Screen Shot " & (current date) & ".png\""
end screenCaptureToDesktop

ALTE LÖSUNG 2

Als ich an einem meiner eigenen Projekte arbeitete, hatte ich eines dieser "EUREKA!" Momente. Hier ist ein völlig anderer Ansatz als mein Code in LÖSUNG 1. Der Ansatz hier bestand darin, den größten Teil meines Codes in Skriptobjekte oder Handler einzuschließen und diese Objekte dann nach Bedarf aufzurufen. In dieser Lösung habe ich dieses Skript als geöffnet bleibende Anwendung mit expliziten Run- und Idle-Handlern gespeichert. Ein Teil des Codes wird ausgeführt, wenn die Anwendung gestartet wird, aber die meisten Befehle werden tatsächlich innerhalb des Idle-Handlers ausgeführt.

Ich denke, diese Lösung ist vielversprechender als LÖSUNG 1.

global allFiles, thisFile, theFileCount, ProgressBar, mainFolder, backupFolder, theDate

on run
    run ProgressBar
end run

on idle
    delay 0.2
    activate
    set theButton to button returned of (display dialog ¬
        "The progress dialog should be gone at this point." buttons {"QUIT", "CONTINUE"} ¬
        default button ¬
        "CONTINUE" with title ¬
        "BACKUP UTILITY" with icon 0 ¬
        giving up after 10)
    if theButton = "QUIT" then
        quit
    else if theButton = "" then
        quit
    else if theButton = "CONTINUE" then
        try
            run ProgressBar
        end try
    end if
    return 1
end idle

on quit
    --  Executed when the script quits
    continue quit -- allows the script to quit
end quit

script ProgressBar
    set mainFolder to choose folder with prompt ¬
        "PLEASE CHOOSE YOUR SOURCE FOLDER TO BACKUP"
    set backupFolder to choose folder with prompt ¬
        "PLEASE CHOOSE YOUR BACKUP DESTINATION FOLDER"
    set theDate to (current date) - (14 * days)
    
    tell application "Finder"
        set allFiles to entire contents of folder mainFolder as alias list
    end tell
    
    set theFileCount to count of allFiles
    
    set progress total steps to theFileCount
    set progress completed steps to 0
    set progress description to "Processing Files..."
    set progress additional description to "Preparing to process."
    
    repeat with theName from 1 to number of items in allFiles
        set this_item to item theName of allFiles
        tell application "Finder"
            duplicate this_item to backupFolder ¬
                with replacing
        end tell
        set progress additional description to ¬
            "Duplicating File " & theName & " of " & theFileCount & ¬
            " to folder " & backupFolder
        set progress completed steps to theName
    end repeat
    
    -- Reset the progress information
    set progress total steps to 0
    set progress completed steps to 0
    set progress description to ""
    set progress additional description to ""
end script