Okay, ich habe das Original und die erste Bearbeitung gelöscht, weil Sie Ihre ursprüngliche Frage so weit bearbeitet haben, dass es einfacher ist, insgesamt eine neue Antwort zu schreiben.

Da Ihre ursprüngliche Frage die folgende Codezeile zeigte , werde ich sie als Beispiel dafür, wie die Variable gesetzt werden kann, einfügen, um Folgendes zu sagen.

Ob die varTextgesetzt wurde von zB:

set varText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

• In which returnis x0Dvs. the richtiger use of linefeed( x0A) Stattdessen in einem Fall, in dem die Variable Daten und keine Wegwerfnachricht ist.

Oder:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

• Wobei jede dieser Zeilen tatsächlich mit einem linefeed( x0A) endet, wie es auf einem Mac sein sollte.

Der do shell script Befehl hat einen Fehler , da er nach dem, was von der Befehlszeile zurückgegeben wird, konvertiert wird x0A, x0Dwobei die erwarteten x0AEndungen zurückgegeben werden. Ich habe dies bestätigt, denn wenn ich Folgendes verwende:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText & " | tee $HOME/Desktop/outfile"

outfileEnthält dann linefeed( x0A) Endungen, so dass dasselbe zurückgegeben wird, do shell scriptaber es konvertiert dann fälschlicherweise die x0AZeilenenden in x0DEndungen, die dann wie folgt behandelt werden können:

Um den Fehler zu berücksichtigen, stellen Sie also immer sicher, dass der Inhalt der übergebenen und zurückgegebenen Variablen x0AZeilenenden enthält, indem Sie den folgenden handlerund Beispielcode verwenden .

Im Folgenden wird davon ausgegangen, dass dies varTextbereits durch eine der oben beschriebenen Methoden festgelegt wurde.

on ensureLinesEndWith0A(varText)
    set varText to paragraphs of varText
    set oldTID to AppleScript's text item delimiters
    set AppleScript's text item delimiters to linefeed
    set varText to varText as string
    set AppleScript's text item delimiters to oldTID
    return varText
end ensureLinesEndWith0A

set varText to ensureLinesEndWith0A(varText)
set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText
set varText to ensureLinesEndWith0A(varText)

Sie könnten dann erneut Folgendes verwenden, um weitere Zeilen aus zu löschen varText:

set varText to ensureLinesEndWith0A(varText)
set varText to do shell script "sed  -e '1d;3d' <<< " & quoted form of varText
set varText to ensureLinesEndWith0A(varText)

Das folgende Bild zeigt ein Beispiel für den zweimaligen Aufruf des do shell script " sed ..." Befehls .

Beispiel:

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed -e '1d;3d' <<< " & quoted form of varText

Kehrt zurück:

"This is sentence 1.
This is sentence 3.
This is sentence 4."

Update: Als Ergebnis einer Entdeckung, die in Edit: of How to delete a specific line of a “return”-based paragraph in AppleScript erwähnt wurde? , lassen Sie mich folgende Aussage treffen:

HINWEIS: Leider enthält das, was in diesem Fall zurückgegeben wird, Wagenrücklaufzeichen (x0D) anstelle der erwarteten Zeilenumbruchzeichen (x0A) und ist meiner Meinung nach ein Fehler !

Es ist ein Fehler, weil: Der do shell script "sed ..." Befehl , wenn er im Terminal damit ausgeführt wird, mit (x0A) nicht (x0D) varTextzurückgibt , wie es sollte. Sogar der kompilierte Befehl im Skripteditor hat immer noch (x0A) nicht (x0D), aber warum er mit (x0D) Absicht des erwarteten (x0A) zurückgegeben wird, ist mir im Moment ein Rätsel und ich werde dies als AppleScript betrachten Fehler, da es nicht das erwartete Verhalten desselben widerspiegelt, wenn es im Terminal ausgeführt wird.\n\rdo shell script "sed ..." \n\r\r\n

Um den Fehler in den Ergebnissen des do shell script "sed ..." Befehls zu berücksichtigen , würde ich folgendermaßen damit umgehen. Verwenden Sie nach dem do shell script "sed ..." Befehl die folgenden Codezeilen :

set newLine to "\n"
set varText to paragraphs of varText
set oldTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to newLine
set varText to varText as string
set AppleScript's text item delimiters to oldTID

Was jetzt zurückgegeben wird, enthält Zeichen für neue Zeilen (x0A) , wie sie beginnen müssten, wenn dieser Fehler nicht vorhanden wäre, und nicht Zeichen für Wagenrücklauf (x0D) .

Hinweis: Nach dem Kompilieren wird die Codezeileset newLine to "\n" wie folgt angezeigt:

set newLine to "
"

Lassen Sie uns dieses Skript in kleinere Teile zerlegen und dann alles in einem AppleScript zusammenfassen.

Dieser Ansatz ist vollständig in AppleScript geschrieben und erfordert keine externen Tools. Die Verwendung externer Tools wie perloder sedführt wahrscheinlich zu viel kürzeren Lösungen, aber Sie haben in anderen Fragen erwähnt, dass Sie AppleScript lernen möchten.

1. Mit Trennzeichen trennen

Sie können das Trennzeichenverhalten von AppleScript verwenden, um eine Zeichenfolge zu teilen . Sie können das Trennzeichen wie gewünscht ändern in return, linefeed, oder sogar Zeichen wie =:

 -- http://macscripter.net/viewtopic.php?id=24473
 to split(someText, delimiter)
     set AppleScript's text item delimiters to delimiter
     set someText to someText's text items
     set AppleScript's text item delimiters to {""} --> restore delimiters to default value
     return someText
 end split

 set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")
 set myLines to split(myText, return)

2. Liste filtern

Mit der zurückgegebenen Liste können Sie die unerwünschten Elemente mithilfe einer Schleife herausfiltern :

 -- http://macscripter.net/viewtopic.php?id=24525
 set indexesToDelete to {1, 4}
 set cleanList to {}

 repeat with i from 1 to count myLines
     if i is not in indexesToDelete then set cleanList's end to myLines's item i
 end repeat

3. Kombinieren Sie die Artikel

Die gefilterte Satzliste kann mit einer weiteren Schleife neu kombiniert werden:

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

Komplett AppleScript

Die Kombination dieser Snippets führt zu folgendem Code:

-- Get the text to work with
set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

-- Split the text into lines based on 'return' delimiter
set myLines to split(myText, return)

-- Filter out indexes 1 and 4 using a loop
set indexesToDelete to {1, 4}
set cleanList to {}
repeat with i from 1 to count myLines
    if i is not in indexesToDelete then set cleanList's end to myLines's item i
end repeat

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

-- Final string
myResult

to split(someText, delimiter)
    set AppleScript's text item delimiters to delimiter
    set someText to someText's text items
    set AppleScript's text item delimiters to {""} --> restore delimiters to default value
    return someText
end split

Das obige Skript könnte durch Kombinieren der Filter- und Rekombinationsschleifen reduziert werden. Ich habe diese als separate Aufgaben belassen, um ihre Rollen besser zu demonstrieren.