Stabile Ringwelt-Interaktivität mit anderen Objekten des Sonnensystems

TL;DR: Ja, spiralförmige Bewegungen um eine Ringwelt herum sind möglich. Bei größeren Entfernungen (≥ 0,04 AE) ist es jedoch alles andere als gleichmäßig.

Zusammenfassung der Ergebnisse:

Für eine toroidale Ringwelt mit Masse$M_R = 3 M_\text{star} = 3M_\odot$, Mittelradius$a = 1 \text{ AU}$und Innenradius$b = 10^{-4} a \simeq 15000\text{ km}$(daher Dichte$\rho \sim 8800\text{ kg/m}^3$, vergleichen mit$\rho_{\text{Fe}}\sim 7800\text{ kg/m}^3$), ist die Beziehung zwischen dem mittleren Abstand vom zentralen Ring der Ringwelt und der Zeitdauer durch die folgende Grafik gegeben:

$\lambda a$ist der Abstand vom zentralen Ring. Die Gleichungen werden mit dem durchschnittlichen (quadratischen) Wert von angepasst$\lambda$über 1 Jahr. Die Mittelwerte (Fünfeck) und Startwerte (Kreis) von$\lambda$werden ebenfalls angezeigt. Die Fehlerbalken zeigen den minimalen und maximalen Wert von an$\lambda$. Schwarz → kein Zentralstern, orange →$M_{\text{star}} = M_{\odot}$.

Die Flugbahn ist tatsächlich spiralförmig.

Wir können uns den projizierten Querschnitt unten ansehen. Die Ringmitte liegt bei$x=-1$(skaliert um$a$, nicht dargestellt), liegt der zentrale Ring des Torus bei$x=0$. Es ist klar, dass die „inneren Abstände“ größer sind als die „äußeren Abstände“, wie man naiv erwarten würde. Wie zuvor schwarz → kein Zentralstern, orange →$M_{\text{star}} = M_{\odot}$. Das erste Diagramm ist durchscheinend, sodass Sie beim Vergrößern beide Querschnitte sehen können.

Physik:

Betrachten Sie der Einfachheit halber ein Punktteilchen; wenn der Satellit zu groß ist (wie groß?), würde es zu Komplikationen durch das Roche-Limit usw. kommen. Ersetzen Sie die Ringwelt (Torus für die Volumenberechnung) durch ihren zentralen Ring für alle anderen Berechnungen. Lassen Sie das Teilchen abgeschossen werden$(x,y,z)=((1-\lambda) a, 0,0)$. Wir betrachten nur das Regime$0.01 \leq \lambda \leq 0.1$. Die untere Grenze verhindert, dass das Teilchen erkennt, dass die Ringwelt durch einen Ring angenähert wurde, und die obere Grenze verhindert, dass seine Umlaufbahn wesentlich durch den Stern gestört wird.

Angenommen, die Radialgeschwindigkeit sei anfangs Null. Die Tangentialgeschwindigkeit für die Umlaufbahn um den Stern (anfänglich$v_y$) sollte ungefähr sein$\sqrt{G M_{\text{star}}/((1-\lambda) a)}$. Die Umlaufgeschwindigkeit um die Ringwelt (anfänglich$v_z$) sollte ungefähr sein$\sqrt{g((1-\lambda) a,0,0) \lambda a}$wo$g(x,y,z)$ist die Größe des Netto-Gravitationsfeldes (auch bekannt als Erdbeschleunigung) als Funktion der Position.

Wir stecken irgendwie fest, ohne eine Nummer für$g((1-\lambda) a,0,0)$.

Das elektrische Potential für einen Ladungsring$Q$ist gegeben als (Ref. 1):

Das Potential für einen Gravitationsring erhält man leicht durch Einsetzen$\epsilon_0 \rightarrow -1/(4\pi G)$und$Q\rightarrow M$in der Gleichung. Man kann den Gradienten (mit a$-$Vorzeichen) und finden Sie das Feld numerisch.

Oder man könnte ein paar Schritte weiter gehen und tatsächlich alles durchrechnen. Verwenden Sie die zuvor gezeigte Gleichung für einen Wert von$M_R$(orange im Diagramm), man kann auf andere Werte von extrapolieren$M_R$verwenden$1/T\propto\sqrt{M_R}$(so lange wie$M_R$ist nicht viel kleiner als$M_S$) wie

Implementierung (Mathematica):

(Alles in SI-Einheiten, sofern nicht anders angegeben.)

Zuerst richten wir die Konstanten ein. Das elliptische Integral für$V$früher ist etwas fies und dauert eine Weile, um zu vereinfachen, also habe ich es einmal vereinfacht und die Definition durch die Ausgabe der Vereinfachung ersetzt.

G = 6.674 10^-11;
EarthMass = 5.9722 10^24;
SolarMass = 333000 EarthMass;
RingMass = 3 SolarMass;
AU = 1.508 10^11;
a = 1 AU;
b = 10^-4 a;
day = 24*3600 // N;
year = 365.25 day;
\[Rho] = RingMass/((2 \[Pi] a) (\[Pi] b^2)) (* roughly 8800, Fe \[Rule] 7800 *) 
(* Math *)
VRing[r_, \[Phi]_, z_, 
   MR_] = -G MR/(2 \[Pi]) ((2 Sqrt[(
       a^2 + r^2 + z^2 - 2 a r Cos[\[Phi]])/((a - r)^2 + 
        z^2)] (EllipticF[\[Pi] - \[Phi]/2, -((
           4 a r)/((a - r)^2 + z^2))] + 
         EllipticF[\[Phi]/2, -((4 a r)/((a - r)^2 + z^2))]))/(Sqrt[
      a^2 + r^2 + z^2 - 2 a r Cos[\[Phi]]]));
VRingxyz[x_, y_, z_, MR_] = 
  TransformedField["Polar" -> "Cartesian", 
   VRing[r, \[Phi], z, MR], {r, \[Phi]} -> {x, y}];
Vtot[x_, y_, z_, MR_, MS_] = -G MS/Norm[{x, y, z}] + 
   VRingxyz[x, y, z, MR];
gRing[x_, y_, z_, MR_] = -Grad[VRingxyz[x, y, z, MR], {x, y, z}];
gtot[x_, y_, z_, MR_, 
   MS_] = -Grad[Vtot[x, y, z, MR, MS], {x, y, z}] /. 
   Abs[p_] Abs'[p_] -> p;
gtotmag[x_, y_, z_, MR_, MS_] = Norm[gtot[x, y, z, MR, MS]];

Lassen Sie uns einen schnellen Plausibilitätscheck machen und sehen, ob das Gravitationsfeld wie erwartet ist.

imgWidth = 2160;
plotAndExport[fname_, 
   plot_] := (Export[NotebookDirectory[] <> fname, 
    Rasterize[plot, ImageSize -> imgWidth]]; plot);
fieldPlotXLim = 1.5/Sqrt[2]; fieldPlotYLim = fieldPlotXLim;
splot = plotAndExport["field.png", #] &@
   Show[StreamPlot[
     Chop@(gtot[x1 a, y1 a, 0, RingMass, SolarMass][[1 ;; 2]])
     , {x1, -fieldPlotXLim, fieldPlotXLim}, {y1, -fieldPlotYLim, 
      fieldPlotYLim}
     , BaseStyle -> {FontSize -> 24}]];

Sieht in Ordnung aus. Das erste Diagramm zeigt den "Fluss" des Feldes (die Pfeilgrößen sind nicht korrekt). Die Größe des Feldes entlang der$x$-Achse wird ebenfalls angezeigt.

Jetzt implementieren wir die Löser für die Partikelbahn.

(* Trajectory solvers with initial conditions *)

xi[\[Lambda]_] := a (1 - \[Lambda]);
yi[\[Lambda]_] := 0.;
zi[\[Lambda]_] := 0.;
vxi[\[Lambda]_] := 0.;
vyi[\[Lambda]_] := Sqrt[G SolarMass/Abs[xi[\[Lambda]]]];
vzi[\[Lambda]_, MR_] := 
  Sqrt[Abs[a - xi[\[Lambda]]] Norm@
     gRing[xi[\[Lambda]], yi[\[Lambda]], zi[\[Lambda]], MR]];
ringSol[\[Lambda]_, MR_, time_] := NDSolve[
   Flatten@{Thread[{xs''[t], ys''[t], zs''[t]} == 
       gRing[xs[t], ys[t], zs[t], MR]],
     xs'[0] == vxi[\[Lambda]], ys'[0] == vyi[\[Lambda]], 
     zs'[0] == vzi[\[Lambda], MR], 
     xs[0] == xi[\[Lambda]], ys[0] == yi[\[Lambda]], 
     zs[0] == zi[\[Lambda]]},
   {xs, ys, zs}, {t, 0, time}];

xiFull[\[Lambda]_] := xi[\[Lambda]];
yiFull[\[Lambda]_] := yi[\[Lambda]];
ziFull[\[Lambda]_] := zi[\[Lambda]];
vxiFull[\[Lambda]_] := vxi[\[Lambda]];
vyiFull[\[Lambda]_, MS_] := Sqrt[G MS/Abs[xi[\[Lambda]]]];
vziFull[\[Lambda]_, MR_, MS_] := 
  Sqrt[Abs[a - xi[\[Lambda]]] Norm@
     gtot[xi[\[Lambda]], yi[\[Lambda]], zi[\[Lambda]], MR, MS]];
fullSol[\[Lambda]_, MR_, MS_, time_, \[Epsilon]_] := NDSolve[
   Flatten@{Thread[{xs''[t], ys''[t], zs''[t]} == 
       gtot[xs[t], ys[t], zs[t], MR, MS]]
     , xs'[0] == vxiFull[\[Lambda]], ys'[0] == vyiFull[\[Lambda], MS],
      zs'[0] == (1 + \[Epsilon]) vziFull[\[Lambda], MR, MS]
     , xs[0] == xiFull[\[Lambda]], ys[0] == yiFull[\[Lambda]], 
     zs[0] == ziFull[\[Lambda]]}
   , {xs, ys, zs}, {t, 0, time}
   ];

appendVelocities[solution_] := 
 Append[solution, {vx -> xs', vy -> ys', vz -> zs'} /. solution]

Wir benötigen eine Reihe von Funktionen, um den Zeitraum zu analysieren.

(* Examining the period T of rotation about the ring *)
(* findPeriod and reconstruct copied from \
https://mathematica.stackexchange.com/a/38221/9332 *)

findPeriod[data_, threshold_] := 
 Module[{fs, s1, s = {}, i, a0f, af, pf, pos, fr, frpos, fdata, 
   fdatac, n, per}, n = Length[data];
  fs = Fourier[data];
  s1 = Drop[fs, -Floor[Length[fs]/2]];
  For[i = 1, i < Length[s1], i++, 
   If[Abs[fs][[i + 1]] > threshold, AppendTo[s, i + 1]]];
  a0f = Abs[fs[[1]]]/Sqrt[n];
  af = 2/Sqrt[n] Abs[fs][[s]];
  pf = Arg[fs][[s]];
  {a0f, Transpose[{s, af, pf}]}]
reconstruct[data_, fp_] := Module[{n}, n = Length[data];
   Show[ListLinePlot[data, PlotStyle -> Black], 
    Plot[fp[[1]] + 
      Sum[fp[[2, j, 2]] Cos[
         2 Pi (fp[[2, j, 1]] - 1)/n t - fp[[2, j, 3]]], {j, 1, 
        Length[fp[[2]]]}], {t, 0, n}, PlotStyle -> Red]]];
getOrbitPeriod[solution_, totalTime_, timeStep_] := Module[{data},
   data = 
    Flatten@Table[
      zs[t timeStep] /. solution, {t, 0, totalTime/timeStep}];
   (* Not strictly correct as there are many frequencies but good \
enough for first approximation *)

   totalTime/(timeStep Sort[
        findPeriod[data, 10^8][[2]], #1[[2]] > #2[[2]] &][[1, 1]])];

(* The period T is observed to be linear in \[Lambda] *)
\
\[Lambda]TFit[\[Lambda]list_, Tlist_] := 
  LinearModelFit[
   Transpose@{\[Lambda]list, Tlist}, \[Lambda], \[Lambda]];

setGraphFontSize = BaseStyle -> {FontSize -> 12};
graphLineWidth = 0.003;
graphMarkerLineWidth = 0.005;
graphMarkerSize = 6;
opacity = 0.5;
polygonMarker[color_, n_] := 
  Graphics[{EdgeForm[{Thickness -> graphMarkerLineWidth, color}], 
    FaceForm[None], Polygon[CirclePoints@n]}, 
   ImageSize -> graphMarkerSize];

coloredListPlot[x_, y_, color_, PM_] := 
  ListPlot[Transpose@{x, y}, PlotStyle -> color, PlotMarkers -> PM];
Needs["ErrorBarPlots`"]
\[Lambda]TFitGraph[{\[Lambda]list_, min\[Lambda]_, max\[Lambda]_, 
   mean\[Lambda]_, median\[Lambda]_}, Tlist_, color_] := 
 Module[{model = \[Lambda]TFit[mean\[Lambda], Tlist]},
  Show[
   Plot[Normal[model], {\[Lambda], 0.01, Max[mean\[Lambda]]}
    , PlotStyle -> {color, Dashed, Thickness -> graphLineWidth}, 
    AxesLabel -> {"\[Lambda]", "T (days)"}
    , PlotLegends -> SwatchLegend[{color}, {Normal[model]}]
    , Evaluate@setGraphFontSize, 
    PlotRange -> {{0, Automatic}, {0, Automatic}}]
   , ErrorListPlot[
    (({{#1, #4}, ErrorBar[{#2 - #1, #3 - #1}, {0, 0}]} &) @@ # &) /@ 
     Transpose@{mean\[Lambda], min\[Lambda], max\[Lambda], Tlist}
    , PlotStyle -> {color, Thickness -> graphLineWidth}, 
    PlotMarkers -> polygonMarker[color, 4]]
   , coloredListPlot[\[Lambda]list, Tlist, 
    color, {Automatic, graphMarkerSize}]
   , coloredListPlot[median\[Lambda], Tlist, color, 
    polygonMarker[color, 5]]
   ]]

Schließlich führen wir die Solver tatsächlich aus und sehen uns die Daten an.

(* Actually run simulations *)

ringSolutionTime = year;
ring\[Lambda]list = Range[0.01, 0.1, 0.01];

AbsoluteTiming[
  ringSolutions = 
   Flatten@appendVelocities@ringSol[#, RingMass, ringSolutionTime] & /@
     ring\[Lambda]list
  ][[1]]

ringPeriods = 
  getOrbitPeriod[#, ringSolutionTime, day] & /@ ringSolutions;
{ringMaxDist, ringMinDist, ringMeanDist, ringMedianDist} = 
  Transpose[distCalc[#, ringSolutionTime, day/24] & /@ ringSolutions];

TableForm@{ring\[Lambda]list, ringMaxDist, ringMinDist, 
  ringMeanDist, ringMedianDist}

fullSolutionTime = year;
full\[Lambda]list = ring\[Lambda]list + 0.005;
AbsoluteTiming[
  fullSolutions = 
   Flatten@appendVelocities@
       fullSol[#, RingMass, SolarMass, fullSolutionTime, 0] & /@ 
    full\[Lambda]list
  ][[1]]

fullPeriods = getOrbitPeriod[#, fullSolutionTime, day] & /@ fullSolutions;
{fullMaxDist, fullMinDist, fullMeanDist, fullMedianDist} = 
  Transpose[distCalc[#, fullSolutionTime, day/24] & /@ fullSolutions];

TableForm@{full\[Lambda]list, fullMaxDist, fullMinDist, 
  fullMeanDist, fullMedianDist}

Das machen$T$vs$\lambda$Plot und Sehen der Flugbahn (Grafiken in Zusammenfassung).

plotAndExport["Tvl.png", #] &@
 Show[
  \[Lambda]TFitGraph[{ring\[Lambda]list, ringMinDist, ringMaxDist, 
    ringMeanDist, ringMedianDist}, ringPeriods, Black]
  , \[Lambda]TFitGraph[{full\[Lambda]list, fullMinDist, fullMaxDist, 
    fullMeanDist, fullMedianDist}, fullPeriods, Orange]
  , PlotRange -> {{0, Automatic}, {0, Automatic}}
  ]
plotAndExport["traj.png", #] &@
 Show[GraphicsGrid[{{
     trajectory[full\[Lambda]list[[1]], fullSolutions[[1]], 
      fullSolutionTime/7]
     , trajectory[full\[Lambda]list[[1]], fullSolutions[[1]], 
      fullSolutionTime]
     }}]]

Verweise:

1. http://physics.oregonstate.edu/portfolios/Activities/EMActivities/ElectricPotentialRing/RingVSolutions070701.pdf

Es gibt Aspekte dieser Frage, die ihre Beantwortung recht schwierig machen. Die physikalische Demonstration von geladenen Tröpfchen, die sich spiralförmig um eine geladene Stricknadel winden, gibt eine vernünftige Vorstellung von dem Konzept, das Sie zu berücksichtigen versuchen. Jede Antwort muss ein Gravitationsfeld für das elektrostatische Feld der Tröpfchen und der Stricknadel ersetzen. Dies ist möglicherweise nicht so einfach. Jeder, der weiß, dass ich mit diesem Vorschlag falsch liege, springt bitte hinein und zerstört ihn.

Es wird vermutet, dass die Ringwelt massiv sein muss, um einen erdähnlichen Planeten in einer spiralförmigen Umlaufbahn um die Ringwelt zu haben. Während angenommen werden kann, dass der erdähnliche Planet eine Masse hat, die der der Erde entspricht, ist das der einfache Teil. Betrachten wir nun die unbekannten Faktoren in diesem Modell.

Die Masse der Ringwelt ist unbekannt. Die Geschwindigkeit des erdähnlichen Planeten ist unbekannt. Die Masse der Ringwelt bestimmt die Gravitationskraft, die auf den Planeten wirkt, um ihn in der Umlaufbahn der Ringwelt zu halten. Während die Geschwindigkeit des Planeten seine Wahrscheinlichkeit bestimmt, seine Umlaufbahn um die Ringwelt aufrechtzuerhalten.

Dies deutet darauf hin, dass die Ringwelt tatsächlich extrem massiv sein muss. Sehr wahrscheinlich wird die Masse der Ringwelt in der Größenordnung einer Sonnenmasse liegen. Das heißt, eine der Sonne ähnliche Masse. In diesem Fall muss die Ringwelt aus ultradichter Materie des von Robert L. Forward in seinem spekulativen Artikel "Far out Physics" ( Analog , August 1975, Seiten 147-166) vorgeschlagenen Typs bestehen .

Der Planet muss sich mit hoher Geschwindigkeit bewegen. Dies ist im Vergleich zu normalen Planetenumlaufbahnen hoch. Die Erde umkreist die Sonne mit einer Geschwindigkeit von 30 km/s. Es ist jedoch nicht einfach, die Beziehung zwischen der Masse der Ringwelt und der Geschwindigkeit des Planeten in einer spiralförmigen Umlaufbahn zu konzeptualisieren. Dies hängt von der Verteilung der Masse entlang der Länge der Ringwelt und der Kraft ab, die sie auf einen Planeten mit Erdmasse ausübt, so dass der Planet in einer spiralförmigen Umlaufbahn um die Ringwelt gehalten werden kann.

Eine besorgniserregende Sache ist die Tatsache, dass die aufgeladenen Tröpfchen am Ende alle auf die aufgeladene Stricknadel fallen. Wenn das gleiche Verhalten auf einen Planeten in einer spiralförmigen Umlaufbahn um eine massive Ringwelt zutrifft, dann stürzt der Planet schließlich auf die ultradichte Oberfläche der Ringwelt. Obwohl dies aufregend und dramatisch ist, wird es für keinen Bewohner des Planeten eine gute Nachricht sein.

Jede Antwort, die eine Lösung für das von der Frage vorgeschlagene Problem liefern kann, muss ein Modell entwickeln, das die Gravitations- und Geschwindigkeitsbeziehung zwischen der Ringwelt und dem Planeten in einer Spiralbahn beschreibt, um die Zeitskala der Umlaufbahn des Planeten und möglicherweise die Stabilität dieses Systems. Derzeit erschweren die unbekannten Faktoren die Bestimmung einer Antwort. Diese Antwort hat die einschränkenden Faktoren des Problems untersucht, konnte jedoch keine Lösung für die Frage des OP vorschlagen.

NACHTRAG:

Das Hauptproblem ist die Form des Gravitationsfeldes einer massiven Ringwelt. Bei Planeten & Sternen konzentriert sich das Gravitationsfeld um eine Punktquelle. Das Feld der Ringwelt hat eine erweiterte Quelle. Der Planet könnte zwei Geschwindigkeitskomponenten haben. Einer die Orbitalgeschwindigkeit um den Stern, der andere eine Orbitalgeschwindigkeit um die Ringwelt. Das würde die Spiralbahn ergeben.

Diese Überlegung legt nun eine mögliche Lösung nahe. Nehmen Sie an, dass die Masse der Ringwelt in einem 12.742 Kilometer breiten Streifen gleich der Masse des Planeten Erde ist. Diese Breite wird gewählt, weil sie dem Durchmesser eines erdähnlichen Planeten entspricht. Dies gibt eine vernünftige Annäherung an das minimale Gravitationsfeld der massiven Ringwelt, um einen Planeten mit der Masse der Erde in einer Umlaufbahn um sie herum zu halten. Angenommen, es hat eine Umlaufgeschwindigkeit von 8 km / s, da dies die Umlaufgeschwindigkeit ist, die erforderlich ist, um einen Satelliten in der Umlaufbahn um einen erdähnlichen Planeten (in diesem Fall den Streifen einer Ringwelt) zu halten.

Der Planet, der die Ringwelt umkreist, wird eine heliozentrische Umlaufgeschwindigkeit von 30 km/s haben, was genau der des Planeten Erde entspricht, und dies ist nur eine Geschwindigkeitskomponente des Planeten. Die andere Geschwindigkeitskomponente lässt den Planeten um die Ringwelt zirkulieren. Die kombinierten Geschwindigkeiten ergeben eine spiralförmige Umlaufbahn um die Ringwelt.

Das OP kann beliebige Dimensionen der Ringwelt anschließen, um die Größe der Umlaufbahn um die Ringwelt festzulegen.

Eine schnelle Berechnung zeigt, dass die Masse der Ringwelt 73.966,237 Erdmassen betragen wird (wobei 1 AE 150.000.00 Kilometer entspricht). Teilen Sie einfach den Umfang der Ringwelt durch 12.742, weil wir angenommen haben, dass jeder 12.742-Kilometer-Streifen eine Erdmasse hat.

Die Umlaufbahn des Planeten um die Ringwelt wird eine hohe Umlaufbahn sein. Möglicherweise so etwas wie eine 48-Stunden-Umlaufbahn, die den Planeten weit von der Ringwelt entfernt hält. Dies sollte den Planeten schützen. Außerdem muss die Ringwelt eine schmale Breite haben. Zum Beispiel rund 12.000 km, das ist richtig, ungefähr der Durchmesser der Erde. Auch dies dient dazu, die spiralförmige Umlaufbahn des Planeten sicher zu machen. Der Radius der Umlaufbahn von der Ringwelt beträgt 220.015,79 km. Es ist nicht sicher, ob diese Umlaufbahn realisierbar ist. Hinweis: Dies setzt voraus, dass die Umlaufgeschwindigkeit 8 km/s beträgt.